Create a new FlashCom application on the server. Within the FlashCom applications directory, create a new subdirectory named surveillance.

Create a new Flash document, and save it as Surveillance.fla.

Within the Flash document, create a new Video symbol in the Library.

Create an instance of the Video symbol on the main timeline, and give it the instance name content_vid. Place the instance approximately in the center of the Stage.

Create a TextArea component instance on the Stage just below the Video object. Use the Properties panel to give it an instance name of ctaLog and change its dimensions to 160 x 200.

Rename the default layer to Contents, and create a new layer above it named Actions.

Select the first keyframe of the Actions layer, and open the Actions panel.

Add the following code to the Actions panel:

// Create the Camera and Microphone objects.
var user_mic = Microphone.get( );
var user_cam = Camera.get( );

// Create the NetConnection object to connect to the server.
var fcs_nc = new NetConnection( );

// Create a NetStream variable.
var record_ns;

// Initialize two Boolean variables to false. They indicate whether the
// activity level is high enough and whether the stream is currently recording.
var activity = false;
var recording = false;

// Set the minimum activity level for the microphone and camera.
user_mic.setSilenceLevel(10, 2000);
user_cam.setMotionLevel(50, 2000);

// Set the camera mode and quality.
user_cam.setMode(320, 240, 30);
user_cam.setQuality(0, 100);

// Attach the video to the Video object.
content_vid.attachVideo(user_cam);

// Connect to the FlashCom application, and open a stream.
fcs_nc.connect("rtmp:/ surveillance");
record_ns = new NetStream(fcs_nc);

// Determine when the microphone and camera are activated and deactivated.
// In all cases, call the calculate( ) function.
user_mic.onActivity = function (activated) {
  calculate(activated);
};

user_cam.onActivity = function (activated) {
  calculate(activated);
};

// calculate( ) determines what action should take place when
// the microphone and/or camera is activated or deactivated.
function calculate (activated) {
  activity = activated;
  if (activity && !recording) {
    startRecording( );
  }
  else if (!activity && recording) {
    pauseRecording( );
  }
};

// Start recording the stream.
function startRecording ( ) {
  recording = true;
  record_ns.attachAudio(user_mic);
  record_ns.attachVideo(user_cam);
  record_ns.publish("security", "append");
  // Display date/time recording begins, such as "Thu Dec 9 22:32:32 GMT-0500 2004"
  ctaLog.text += "Started recording" + new Date( ) + newline;
}

// Stop recording the stream.
function pauseRecording ( ) {
  recording = false;
  record_ns.publish(false);
  ctaLog.text += "Paused recording" + new Date( ) + newline;
}

// Initialize application by starting to record.
startRecording( );

Test the movie. You should see the TextArea report when the video is recording and pausing.

Create a new Flash document, and save it as SurveillanceView.fla.

Create a new Video symbol in the Library of SurveillanceView.fla.

Create an instance of the Video object on the Stage, and give it an instance name of content_vid.

Rename the default layer to Content, and create a new layer named Actions.

Select the first keyframe of the Actions layer, and open the Actions panel.

Add the following code to the Actions panel:

// Create the NetConnection object, and connect to the FlashComm
// application on the server.
var fcs_nc = new NetConnection(  );
fcs_nc.connect("rtmp:/surveillance");

// Create the NetStream object, and play back the stream.
var playback_ns = new NetStream(fcs_nc);
playback_ns.play("security");
content_vid.attachVideo(playback_ns);

Test the movie. You should see the surveillance stream play. Only the portions in which the activity level was high enough were recorded.